Archived Forums

Public Sub AddFeatureCountToTOC()
Dim pMxDoc As IMxDocument
Dim pLyr As ILayer
Dim pFtrLyr As IFeatureLayer
Dim pFtrLyrDef As IFeatureLayerDefinition
Dim pQryFltr As IQueryFilter

    Set pMxDoc = ThisDocument
    Set pLyr = pMxDoc.SelectedLayer
    If Not (TypeOf pLyr Is IFeatureLayer) Then Exit Sub
    
    Set pFtrLyr = pLyr
    Set pFtrLyrDef = pFtrLyr
    If pFtrLyrDef.DefinitionExpression = "" Then
        Set pQryFltr = Nothing
    Else
        Set pQryFltr = New QueryFilter
        pQryFltr.SubFields = ""
        pQryFltr.WhereClause = pFtrLyrDef.DefinitionExpression
    End If
    
    pFtrLyr.Name = pFtrLyr.Name + " (Features: " + CStr(pFtrLyr.FeatureClass.FeatureCount(pQryFltr)) + ")"
    pMxDoc.UpdateContents

End Sub

Public Sub LabelClassBreaks()
Dim pMxDoc As IMxDocument
Dim pGeoFtrLyr As IGeoFeatureLayer
Dim pClsBrkRend As IClassBreaksRenderer

    ' Get the Class Break Renderer of the selected layer
    Set pMxDoc = ThisDocument
    Set pGeoFtrLyr = pMxDoc.SelectedLayer
    Set pClsBrkRend = pGeoFtrLyr.Renderer
    
    ' Get the field name used in the class break
    ' and encapsulate it correctly
    Dim fldName As String
    fldName = pClsBrkRend.Field
    Dim pDataset As IDataset
    Set pDataset = pGeoFtrLyr.FeatureClass
    If pDataset.Workspace.WorkspaceFactory.WorkspaceType = esriFileSystemWorkspace Then
        fldName = """" + fldName + """"
    Else
        fldName = "[" + fldName + "]"
    End If
    
    ' Create a query filter
    Dim pQryFltr As IQueryFilter
    Set pQryFltr = New QueryFilter
    pQryFltr.SubFields = ""
    
    ' Loop through the breaks getting the record counts
    Dim ftrCnt As Long
    Dim cb As Long
    For cb = 0 To pClsBrkRend.BreakCount - 1
        If cb = 0 Then
            pQryFltr.WhereClause = fldName + " <= " + CStr(pClsBrkRend.Break(cb))
        Else
            pQryFltr.WhereClause = fldName + " > " + CStr(pClsBrkRend.Break(cb - 1)) + _
                " AND " + fldName + " <= " + CStr(pClsBrkRend.Break(cb))
        End If
        ftrCnt = pGeoFtrLyr.FeatureClass.FeatureCount(pQryFltr)
        pClsBrkRend.Label(cb) = pClsBrkRend.Label(cb) + " (RecCnt: " + CStr(ftrCnt) + ")"
    Next cb
    
    pMxDoc.UpdateContents

End Sub

Public Sub LabelSimpleAndClassBreaks()
Dim pMxDoc As IMxDocument
Dim pGeoFtrLyr As IGeoFeatureLayer
Dim pSimpRend As ISimpleRenderer
Dim pClsBrkRend As IClassBreaksRenderer
Dim pTbl As ITable
Dim ftrCnt As Long

    ' Get the selected layer
    Set pMxDoc = ThisDocument
    Set pGeoFtrLyr = pMxDoc.SelectedLayer
    Set pTbl = pGeoFtrLyr
    
    ' Check the renderer type
    If TypeOf pGeoFtrLyr.Renderer Is ISimpleRenderer Then
    
        ' Simple Renderer
        Set pSimpRend = pGeoFtrLyr.Renderer
        ftrCnt = pTbl.RowCount(Nothing)
        pSimpRend.Label = pSimpRend.Label + " (RecCnt: " + CStr(ftrCnt) + ")"
    
    Else
        
        'Class-break renderer
        Set pClsBrkRend = pGeoFtrLyr.Renderer
        
        ' Get the field name used in the class break
        ' and encapsulate it correctly
        Dim fldName As String
        fldName = pClsBrkRend.Field
        Dim pDataset As IDataset
        Set pDataset = pGeoFtrLyr.FeatureClass
        If pDataset.Workspace.WorkspaceFactory.WorkspaceType = esriFileSystemWorkspace Then
            fldName = """" + fldName + """"
        Else
            fldName = "[" + fldName + "]"
        End If
        
        ' Create a query filter
        Dim pQryFltr As IQueryFilter
        Set pQryFltr = New QueryFilter
        pQryFltr.SubFields = ""
        
        ' Loop through the breaks getting the record counts
        Dim cb As Long
        For cb = 0 To pClsBrkRend.BreakCount - 1
            If cb = 0 Then
                pQryFltr.WhereClause = fldName + " <= " + CStr(pClsBrkRend.Break(cb))
            Else
                pQryFltr.WhereClause = fldName + " > " + CStr(pClsBrkRend.Break(cb - 1)) + _
                    " AND " + fldName + " <= " + CStr(pClsBrkRend.Break(cb))
            End If
            ftrCnt = pTbl.RowCount(pQryFltr)
            pClsBrkRend.Label(cb) = pClsBrkRend.Label(cb) + " (RecCnt: " + CStr(ftrCnt) + ")"
        Next cb
        
    End If
    
    ' Refresh the TOC
    pMxDoc.UpdateContents

End Sub